This page contains 33 series and integral representations for Catalan's constant. Most of these formulas are proved just by evaluating them directly in Mathematica. Others are proved by a few steps of Mathematica computation
In[1]:= Integrate[ArcTan[x]/x, {x, 0, 1}]
Out[1]= Catalan
In[2]:= -Integrate[Log[x]/(x^2 + 1), {x, 0, 1}]
Out[2]= Catalan
In[3]:= 1/2*Integrate[x*Sech[x], {x, 0, Infinity}]
Out[3]= Catalan
In[4]:= -2*Integrate[Log[2*Sin[x]], {x, 0, Pi/4}]
-Catalan I 2 Pi Log[1 - I] Pi Log[2]
Out[4]= -2 (-------- - -- Pi - ------------- + ---------)
2 16 4 8
In[5]:= FullSimplify[%]
Out[5]= Catalan
In[6]:= 2*Integrate[Log[2*Cos[x]], {x, 0, Pi/4}]
2
8 Catalan + I Pi - 4 Pi Log[1 + I] + 2 Pi Log[2]
Out[6]= -------------------------------------------------
8
In[7]:= FullSimplify[%]
Out[7]= Catalan
From 4 and 5 it immediately follows
Actually formulas 4 and 5 are particular cases of the following more general representations
where p is a positive integer.
In[8]:= -(1/4)*Pi*Log[2] + Integrate[(x*Csc[x])/(Cos[x] + Sin[x]), {x, 0, Pi/2}]
Out[8]= Catalan
Here are related representations:
In[9]:= 1/4*Pi*Log[2] - Integrate[(x*Csc[x])/(Cos[x] - Sin[x]), {x, 0, Pi/2}, PrincipalValue -> True]
Out[9]= Catalan
In[10]:= (7*Zeta[3])/(4*Pi) + 2/Pi*Integrate[ArcTan[x]^2/x, {x, 0, 1}]
4 Catalan Pi - 7 Zeta[3] 7 Zeta[3]
Out[10]= ------------------------ + ---------
4 Pi 4 Pi
In[11]:= Expand[%]
Out[11]= Catalan
In[12]:= 1/2*Integrate[x/Sin[x], {x, 0, Pi/2}]
Out[12]= Catalan
In[13]:= (7*Zeta[3])/(4*Pi) + 1/(2*Pi)*Integrate[x^2/Sin[x], {x, 0, Pi/2}]
2 2
Out[13]= (8 Catalan Pi + Pi Log[1 - I] - Pi Log[1 + I] - 8 PolyLog[3, -I] +
7 Zeta[3]
> 8 PolyLog[3, I] - 14 Zeta[3]) / (8 Pi) + ---------
4 Pi
It is known that the polylogarithm of roots of unity can be expressed in terms of derivatives of the gamma function
where parameters p and q are integer. From here by setting p=3, q=4 and p=1, q=4 we obtain
Applying them to the Out[13], we have
In[14]:= %/. {
PolyLog[n_, -I] :> -(I*(-(1/4))^n*
(PolyGamma[n - 1, 1/4] - PolyGamma[n - 1, 3/4]))/Gamma[n] -
((-2 + 2^n)*Zeta[n])/2^(2*n),
PolyLog[n_, I] :> (I*(-1/4))^n*
(PolyGamma[n - 1, 1/4] - PolyGamma[n - 1, 3/4]))/Gamma[n] -
((-2 + 2^n)*Zeta[n])/2^(2*n)
}
2 2
Out[15]= (8 Catalan Pi + Pi Log[1 - I] - Pi Log[1 + I] +
-I 1 3 3 Zeta[3]
> 8 (--- (PolyGamma[2, -] - PolyGamma[2, -]) - ---------) -
128 4 4 32
I 1 3 3 Zeta[3]
> 8 (--- (PolyGamma[2, -] - PolyGamma[2, -]) - ---------) - 14 Zeta[3])\
128 4 4 32
7 Zeta[3]
> / (8 Pi) + ---------
4 Pi
In[16]:= FullSimplify[%]
Out[16]= Catalan
Formulas 9 and 10 are particular cases of the more general integral
where p is a positive integer.
In[17]:= -Integrate[Log[(1 - x)/Sqrt[2]]/(x^2 + 1), {x, 0, 1}]
I 1 I 1 I 1 I
Out[17]= - (Log[- - -] Log[2] - Log[- + -] Log[2] + 2 PolyLog[2, - - -] -
4 2 2 2 2 2 2
1 I
> 2 PolyLog[2, - + -])
2 2
From the Landen identity for the dilogarithm
with z=1/2-i/2 and z = 1/2+i/2 follows
respectively. Applying them to the Out[17], we obtain
In[18]:= %/.{
PolyLog[2, 1/2 - I/2] -> -I*Catalan + Pi^2/48 - 1/2*Log[1/2 + I/2]^2,
PolyLog[2, 1/2 + I/2] -> I*Catalan + Pi^2/48 - 1/2*Log[1/2 - I/2]^2
}
1 I 2
2 Log[- - -]
I Pi 2 2
Out[18]= - (-2 (I Catalan + --- - -----------) +
4 48 2
1 I 2
2 Log[- + -]
Pi 2 2 1 I
> 2 (-I Catalan + --- - -----------) + Log[- - -] Log[2] -
48 2 2 2
1 I
> Log[- + -] Log[2])
2 2
In[19]:= FullSimplify[%]
Out[19]= Catalan
In[20]:= -Integrate[Log[1/2*(1 - x^2)]/(x^2 + 1), {x, 0, 1}]
I 2 2 2 1 I
Out[20]= - (Pi + Log[-1 - I] - Log[-1 + I] - 2 I Pi Log[- - -] +
4 2 2
1 I 1 I
> 2 I Pi Log[- + -] + I Pi Log[2] + 2 PolyLog[2, - - -] -
2 2 2 2
1 I
> 2 PolyLog[2, - + -])
2 2
We will proceed in the same manner as in the previous section
In[21]:= %/.{
PolyLog[2, 1/2 - I/2] -> -I*Catalan + Pi^2/48 - 1/2*Log[1/2 + I/2]^2,
PolyLog[2, 1/2 + I/2] -> I*Catalan + Pi^2/48 - 1/2*Log[1/2 - I/2]^2
}
I 2 2 2 1 I
Out[21]= - (Pi + Log[-1 - I] - Log[-1 + I] - 2 I Pi Log[- - -] -
4 2 2
1 I 2
2 Log[- - -]
Pi 2 2 1 I
> 2 (I Catalan + --- - -----------) + 2 I Pi Log[- + -] +
48 2 2 2
1 I 2
2 Log[- + -]
Pi 2 2
> 2 (-I Catalan + --- - -----------) + I Pi Log[2])
48 2
In[22]:= FullSimplify[%]
Out[22]= Catalan
In[23]:= 1/8*Pi*Log[Sqrt[3] + 2] + 3/4*Integrate[x/Sin[x], {x, 0, Pi/6}]
Pi Log[2 + Sqrt[3]] I
Out[23]= ------------------- + --
8 16
2 1/6 1/6
> (3 Pi - 2 I Pi Log[1 - (-1) ] + 2 I Pi Log[1 + (-1) ] +
1/6 1/6
> 12 PolyLog[2, -(-1) ] - 12 PolyLog[2, (-1) ])
From the reflection formula for the dilogarithm
with 
it follows
Applying it to the result of integration Out[23], we have
In[24]:= FullSimplify[%/.PolyLog[2, -(-1)^(1/6)] -> (-11*Pi^2)/72 - PolyLog[2, (-1)^(5/6)]]
I 2
Out[24]= -- (Pi - 6 I Pi Log[2 - Sqrt[3]] - 6 I Pi Log[2 + Sqrt[3]] -
96
1/6 5/6
> 72 PolyLog[2, (-1) ] - 72 PolyLog[2, (-1) ])
In[25]:= %/.r_ Log[w_] + r_ Log[e_] :> r Log[w e//Expand]
I 2 1/6 5/6
Out[25]= -- (Pi - 72 PolyLog[2, (-1) ] - 72 PolyLog[2, (-1) ])
96
In[26]:= Collect[%, Pi, Simplify]
I 2 3 I 1/6 5/6
Out[26]= -- Pi - --- (PolyLog[2, (-1) ] + PolyLog[2, (-1) ])
96 4
Using the following well-known property of the dilogarithm
with t=-i and q=3, we derive
Applying this formula to Out[26], we finally obtain
In[27]:= %/.PolyLog[2, (-1)^(1/6)] + PolyLog[2, (-1)^(5/6)] -> (4*I)/3*Catalan + Pi^2/72
2
I 2 3 I 4 I Pi
Out[27]= -- Pi - --- (--- Catalan + ---)
96 4 3 72
In[28]:= Expand[%]
Out[28]= Catalan
In[29]:= -(Pi^2/4)*Integrate[(x - 1/2)*Sec[Pi*x], {x, 0, 1}]
3 3
Out[29]= (32 Catalan - Pi HypergeometricPFQ[{1, 1, -, -}, {2, 2, 2}, 1] +
2 2
> 8 Pi Log[4]) / 64
To force Mathematica to do this quite simple integral, we need to divide the interval of integration into two parts (0,1/2) and (1/2,1) and then change the variable x -> 1-z in the first integral. This leads to the following identity
the right side of which can be easily evaluated:
In[30]:= -(Pi^2/2)*Integrate[(x - 1/2)*Sec[Pi*x], {x, 1/2, 1}]
Out[30]= Catalan
In[31]:= 1/2*Integrate[EllipticK[x^2], {x, 0, 1}]
1 1 1 3
Pi HypergeometricPFQ[{-, -, -}, {1, -}, 1]
2 2 2 2
Out[31]= ------------------------------------------
4
To see how this integral can be evaluated to Catalan`s constant we have to use the integral representation for the elliptic function K(x):
Substituting it into the given integral and changing the order of integration, we have
Now we can use Mathematica to evaluate integrals from the right side:
In[32]:= Integrate[1/Sqrt[1 - x^2*Sin[t]^2], {x, 0, 1}]
Out[32]= ArcSin[Sin[t]] Csc[t]
In[33]:= 1/2*Integrate[PowerExpand[%], {t, 0, Pi/2}]
Out[33]= Catalan
In[34]:= -(1/2) + Integrate[EllipticE[x^2], {x, 0, 1}]
1 1 1 3
Pi HypergeometricPFQ[{-(-), -, -}, {1, -}, 1]
1 2 2 2 2
Out[34]= -(-) + ---------------------------------------------
2 2
In the same manner as in the previous section using the integral representations for the elliptic function E(x):
we have
The integrals in the right side of this equality can be successfully computed by Mathematica:
In[35]:= Integrate[Sqrt[1 - x^2*Sin[t]^2], {x, 0, 1}]
2
Sqrt[Cos[t] ] + ArcSin[Sin[t]] Csc[t]
Out[35]= -------------------------------------
2
In[36]:= -(1/2) + Integrate[PowerExpand[%], {t, 0, Pi/2}]
Out[36]= Catalan
In[37]:= Integrate[ArcSinh[Sin[x]], {x, 0, Pi/2}]
Pi
Out[37]= Integrate[ArcSinh[Sin[x]], {x, 0, --}]
2
The integral can be evaluated to Catalan`s constant by using the integral
representation for 
Substituting it into the given integral and changing the order of integration, we have
Then with use of Mathematica we obtain the desirable result
In[38]:= Integrate[Integrate[Sin[x]/Sqrt[t^2*Sin[x]^2 + 1], {x, 0, Pi/2}], {t, 0, 1}]
Out[38]= Catalan
It follows immediately from 17 that
To prove this we consider the more general integral
where p is an arbitrary parameter. Evaluating this integral with Mathematica, we have
In[39]:= 1/4 Integrate[x^p/(Sqrt[1-x] Sqrt[1-y] (x+y)), {y, 0, 1}, {x, 0, 1},
GenerateConditions -> False] //Expand
3/2 1 p
-(Pi Csc[p Pi] Gamma[- + -])
2 2
Out[39]= ------------------------------- +
p
4 p Gamma[-]
2
1 3
Sqrt[Pi] Gamma[p] HypergeometricPFQ[{1, 1, - - p}, {-, 1 - p}, -1]
2 2
> ------------------------------------------------------------------
1
2 Gamma[- + p]
2
Now we need to find the limit of this expression when p tends to infinity. At first we find the asymptotic expansion of HypergeometricPFQ. For that we convert the hypergeometric function into the series and consider the summand:
In[40]:= HypergeometricPFQ[{1,1,1/2-p},{3/2,1-p},-1]/.
HypergeometricPFQ[a_,b_,z_] :>
(Times@@Pochhammer[a,k])/(Times@@Pochhammer[b,k]) z^k/k!
k 2 1
(-1) Pochhammer[1, k] Pochhammer[- - p, k]
2
Out[40]= --------------------------------------------
3
k! Pochhammer[-, k] Pochhammer[1 - p, k]
2
In[41]:= FunctionExpand[%]
k 1
(-1) Sqrt[Pi] Gamma[1 + k] Gamma[1 - p] Gamma[- + k - p]
2
Out[41]= ---------------------------------------------------------
3 1
2 Gamma[- + k] Gamma[- - p] Gamma[1 + k - p]
2 2
Then we expand this with respect to p at the neighborhood of zero:
In[42]:= Series[%, {p, 0, 1}]//Normal//FullSimplify
Out[42]= -(
k 1
(-1) (-1 + p Log[4] + p PolyGamma[0, - + k] - p PolyGamma[0, 1 + k])
2
> ---------------------------------------------------------------------)
1 + 2 k
In[43]:= %/.PolyGamma[0,1/2+k] -> PolyGamma[0,3/2+k]-2/(1+2k)
k
Out[43]= -(((-1) (-1 + p Log[4] - p PolyGamma[0, 1 + k] +
-2 3
> p (------- + PolyGamma[0, - + k]))) / (1 + 2 k))
1 + 2 k 2
and sum it up
In[44]:= Sum[%, {k,0,Infinity}]//Simplify
8 Catalan p + Pi - 3 p Pi Log[2]
Out[44]= --------------------------------
4
We obtain the folowing asymptotic formula
Substituting it into the result of the integratyion Out[39], we finally prove the given identity
In[45]:= %39/.HypergeometricPFQ[{1,1,1/2-p},{3/2,1-p},-1]->%
3/2 1 p
-(Pi Csc[p Pi] Gamma[- + -])
2 2
Out[45]= ------------------------------- +
p
4 p Gamma[-]
2
Sqrt[Pi] Gamma[p] (8 Catalan p + Pi - 3 p Pi Log[2])
> ----------------------------------------------------
1
8 Gamma[- + p]
2
In[46]:= Series[%, {p, 0, 0}]//Normal//FullSimplify
Out[46]= Catalan
The above integral can be generalized to this one
which generates Catalan's number when a, b, c and d are positive integers.
In[47]:= Sum[(-1)^k/(2*k + 1)^2, {k, 0, Infinity}]
Out[47]= Catalan
In[48]:= -(Pi^2/8) + 2*Sum[1/(4*k + 1)^2, {k, 0, Infinity}]
2 2
-Pi 8 Catalan + Pi
Out[48]= ---- + ---------------
8 8
In[49]:= Expand[%]
Out[49]= Catalan
In[50]:= Pi^2/8 - 2*Sum[1/(4*k + 3)^2, {k, 0, Infinity}]
2 2
Pi 8 Catalan - Pi
Out[50]= --- + ---------------
8 8
In[51]:= Expand[%]
Out[51]= Catalan
In[52]:= 1/2*Sum[(4^k*k!^2)/((2*k)!*(2*k + 1)^2), {k, 0, Infinity}]
Out[52]= Catalan
In[53]:= 1/2*Log[2]*Pi + Sum[((-1)^k*(PolyGamma[k + 1] + EulerGamma))/(2*k + 1), {k, 0, Infinity}]
EulerGamma Pi Pi Log[2] 4 Catalan - EulerGamma Pi - 2 Pi Log[2]
Out[53]= ------------- + --------- + ---------------------------------------
4 2 4
In[54]:= Expand[%]
Out[54]= Catalan
In[55]:= 1/4*Pi*Log[2] + Sum[((-1)^k*(PolyGamma[k + 3/2] + EulerGamma))/(2*k + 1), {k, 0, Infinity}]
EulerGamma Pi Pi Log[2] 4 Catalan - EulerGamma Pi - Pi Log[2]
Out[55]= ------------- + --------- + -------------------------------------
4 4 4
In[56]:= Expand[%]
Out[56]= Catalan
In[57]:= 1 - Sum[(k*Zeta[2*k + 1])/4^(2*k), {k, 1, Infinity}]
Out[57]= Catalan
In[58]:= 1/16*Sum[((3^k - 1)*(k + 1)*Zeta[k + 2])/4^k, {k, 1, Infinity}]
Out[58]= Catalan
In[59]:= 1/8*Sum[k/2^k*Zeta[k + 1, 3/4], {k, 2, Infinity}]
Out[59]= Catalan
In[60]:= 1 - 1/8*Sum[k/2^k*Zeta[k + 1, 5/4], {k, 2, Infinity}]
Out[60]= Catalan
In[61]:= 1/2*Pi*Log[2] - 1/32*Pi*Sum[(2*k + 1)!^2/(16^k*k!^4*(k + 1)^3), {k, 0, Infinity}]
3 3
-(Pi HypergeometricPFQ[{1, 1, -, -}, {2, 2, 2}, 1])
2 2 Pi Log[2]
Out[61]= --------------------------------------------------- + ---------
32 2
Catalan`s constant pops up immediately taking into account the result of the section 14.
In[62]:= -(1/4)*Pi*Log[2] + Sqrt[2]*Sum[(2*k)!/(8^k*k!^2*(2*k + 1)^2), {k, 0, Infinity}]
1 1 1 3 3 1 Pi Log[2]
Out[62]= Sqrt[2] HypergeometricPFQ[{-, -, -}, {-, -}, -] - ---------
2 2 2 2 2 2 4
We observe that
Substituting it into the above series and changing the order of summation and integration, we obtain
Series and integral in the right side of this equality can be easily evaluated by Mathematica
In[63]:= Sum[((2*k)!*t^(2*k))/(8^k*k!^2*(2*k + 1)), {k, 0, Infinity}]
2
Sqrt[t ]
Sqrt[2] ArcSin[--------]
Sqrt[2]
Out[63]= ------------------------
2
Sqrt[t ]
In[64]:= PowerExpand[%, t]
t
Sqrt[2] ArcSin[-------]
Sqrt[2]
Out[64]= -----------------------
t
In[65]:= Integrate[%, {t, 0, 1}]
2
8 Sqrt[2] Catalan + I Sqrt[2] Pi + 4 Sqrt[2] Pi Log[1 - I]
Out[65]= -----------------------------------------------------------
16
Finally, we have
In[66]:= -(1/4)*Pi*Log[2] + Sqrt[2]*%
2
8 Sqrt[2] Catalan + I Sqrt[2] Pi + 4 Sqrt[2] Pi Log[1 - I]
Out[66]= ----------------------------------------------------------- -
8 Sqrt[2]
Pi Log[2]
> ---------
4
In[67]:= FullSimplify[%]
Out[67]= Catalan
In[68]:= 1/8*Pi*Log[Sqrt[3] + 2] + 3/8*Sum[k!^2/((2*k)!*(2*k + 1)^2), {k, 0, Infinity}]
1 3 3 1
3 HypergeometricPFQ[{-, 1, 1}, {-, -}, -]
2 2 2 4 Pi Log[2 + Sqrt[3]]
Out[68]= ----------------------------------------- + -------------------
8 8
In the the same manner as in the previous section we obtain
Using Mathematica we evaluate the sum and the integral in the right side
In[69]:= Sum[(k!^2*t^(2*k))/((2*k)!*(2*k + 1)), {k, 0, Infinity}]
2
Sqrt[t ]
2 ArcSin[--------]
2
Out[69]= ---------------------
2
2 t
Sqrt[t ] Sqrt[1 - --]
4
In[70]:= PowerExpand[%, t]
t
2 ArcSin[-]
2
Out[70]= --------------
2
t
t Sqrt[1 - --]
4
In[71]:= Integrate[%, {t, 0, 1}]
I 2 1/6 1/6
Out[71]= - (3 Pi - 2 I Pi Log[1 - (-1) ] + 2 I Pi Log[1 + (-1) ] +
6
1/6 1/6
> 12 PolyLog[2, -(-1) ] - 12 PolyLog[2, (-1) ])
Thus, the given sum is
In[72]:= 1/8*Pi*Log[Sqrt[3] + 2] + (3*%)/8
Pi Log[2 + Sqrt[3]] I
Out[72]= ------------------- + --
8 16
2 1/6 1/6
> (3 Pi - 2 I Pi Log[1 - (-1) ] + 2 I Pi Log[1 + (-1) ] +
1/6 1/6
> 12 PolyLog[2, -(-1) ] - 12 PolyLog[2, (-1) ])
which could be further simplified by using the transformation rules from the section 14:
In[73]:= % /. {
PolyLog[2, -(-1)^(1/6)] -> -((11*Pi^2)/72) - PolyLog[2, (-1)^(5/6)],
PolyLog[2, (-1)^(1/6)] -> (4*I)/3*Catalan + Pi^2/72 - PolyLog[2, (-1)^(5/6)]
}
Pi Log[2 + Sqrt[3]] I
Out[73]= ------------------- + --
8 16
2 1/6 1/6
> (3 Pi - 2 I Pi Log[1 - (-1) ] + 2 I Pi Log[1 + (-1) ] +
2
-11 Pi 5/6
> 12 (------- - PolyLog[2, (-1) ]) -
72
2
4 I Pi 5/6
> 12 (--- Catalan + --- - PolyLog[2, (-1) ]))
3 72
In[74]:= FullSimplify[%]
16 Catalan + Pi Log[2 - Sqrt[3]] + Pi Log[2 + Sqrt[3]]
Out[74]= ------------------------------------------------------
16
In[75]:= %/.r_ Log[w_] + r_ Log[e_] :> r Log[w e//Expand]
Out[75]= Catalan
In[76]:= (Pi*EulerGamma)/8 + 1/4*Pi*Log[2] + 1/4*Sum[(2^k*k!^2*PolyGamma[0, 3/2 + k])/(1 + 2*k)!, {k, 0, Infinity}]
EulerGamma Pi Pi Log[2]
Out[76]= ------------- + --------- +
8 4
k 2 3
2 k! PolyGamma[0, - + k]
2
Sum[--------------------------, {k, 0, Infinity}]
(1 + 2 k)!
> -------------------------------------------------
4
Mathematica proof is possible but quite complicated. First of all by using the following property of the polygamma function:
we divide the given sum in two sums:
and evaluate each of them separately. The first sum can be rewritten as
and then evaluated
In[77]:= Sum[(2^k*k!^2*t^(2*k))/(2*k + 1)!, {k, 0, Infinity}]
2
Sqrt[t ]
Sqrt[2] ArcSin[--------]
Sqrt[2]
Out[77]= ------------------------
2
2 t
Sqrt[t ] Sqrt[1 - --]
2
In[78]:= Integrate[PowerExpand[%, t], {t, 0, 1}]
2 1/4
Out[78]= (I Sqrt[2] Pi + Sqrt[2] Pi Log[1 - (-1) ] -
1/4 1/4
> Sqrt[2] Pi Log[1 + (-1) ] + 4 I Sqrt[2] PolyLog[2, -(-1) ] -
1/4
> 4 I Sqrt[2] PolyLog[2, (-1) ]) / 4
In[79]:= FullSimplify[%]
2 1/4
Out[79]= (-48 Catalan + 23 I Pi + 24 Pi Log[1 - (-1) ] -
1/4 1/4
> 24 Pi Log[1 + (-1) ] - 192 I PolyLog[2, (-1) ]) / (48 Sqrt[2])
Let us name the first sum as sum1:
In[80]:= sum1=2 %;
Now we consider the second sum:
At first we need to introduce special values of Tan and Cot at Pi/8:
In[81]:= Unprotect[Tan, Cot]; In[82]:= Tan[Pi/8] = Sqrt[2] - 1; Cot[Pi/8] = Sqrt[2] + 1; In[83]:= Protect[Tan, Cot];
Then with the use of Mathematica we calculate that sum :
In[84]:= FullSimplify[Sum[(2^k*k!^2*PolyGamma[0, k + 1/2])/(2*k + 1)!, {k, 0, Infinity}]]
2
Out[84]= (-2 I (-3 + Sqrt[2]) Pi - 8 ArcCot[1 + Sqrt[2]] Log[2] +
> ArcCot[1 - Sqrt[2]] Log[256] +
> 16 ArcCot[1 + Sqrt[2]] Log[2 - Sqrt[2]] -
> 16 ArcCot[1 - Sqrt[2]] Log[2 + Sqrt[2]] +
> Pi (-2 EulerGamma - 2 I (-8 + Sqrt[2]) ArcCot[1 - Sqrt[2]] +
> 2 I Sqrt[2] ArcCot[1 + Sqrt[2]] - 8 ArcSinh[1] - 6 Log[2] +
> 5 Log[2 - Sqrt[2]] - Sqrt[2] Log[2 - Sqrt[2]] +
> 3 Log[2 + Sqrt[2]] + Sqrt[2] Log[2 + Sqrt[2]] - Log[99 + 70 Sqrt[2]]
1 I 1 I
> ) + 8 I PolyLog[2, - - -] - 8 I PolyLog[2, - + -] -
2 2 2 2
-1 - I 1 + I
> 8 I Sqrt[2] PolyLog[2, -------] + 8 I Sqrt[2] PolyLog[2, -------] +
Sqrt[2] Sqrt[2]
-1 + I 1 - I
> 8 I PolyLog[2, ------------] - 8 I PolyLog[2, -----------] -
-2 + Sqrt[2] 2 + Sqrt[2]
(1 + I) Sqrt[2] (1 + I) Sqrt[2]
> 8 I PolyLog[2, ---------------] + 8 I PolyLog[2, ---------------]) / 4
-2 + 2 Sqrt[2] 2 + 2 Sqrt[2]
Further simplifications can be done by applying the following set of transformation rules :
In[85]:= % /. {
PolyLog[2, 1/2 - I/2] -> -I*Catalan + Pi^2/48 + 1/32*(Pi + 2*I*Log[2])^2,
PolyLog[2, 1/2 + I/2] -> I*Catalan + Pi^2/48 + 1/32*(Pi - 2*I*Log[2])^2,
PolyLog[2, -((1 + I)/Sqrt[2])] -> PolyLog[2, -(-1)^(1/4)],
PolyLog[2, (1 + I)/Sqrt[2]] -> PolyLog[2, (-1)^(1/4)],
PolyLog[2, ((1 + I)*Sqrt[2])/(-2 + 2*Sqrt[2])] ->
-Pi^2/6 - 1/2*Log[-(-1)^(1/4)*(1 + Sqrt[2])]^2 - PolyLog[2, -(-1)^(3/4)/(1 +Sqrt[2])],
PolyLog[2, ((1 + I)*Sqrt[2])/(2 + 2*Sqrt[2])] -> PolyLog[2,(-1)^(1/4)/(1 + Sqrt[2])],
PolyLog[2, (1 - I)/(2 + Sqrt[2])] -> PolyLog[2, -((-1)^(3/4)/(1 + Sqrt[2]))],
PolyLog[2, -((1 - I)/(-2 + Sqrt[2]))] ->
-Pi^2/6 - 1/2*Log[(-1)^(3/4)*(1 + Sqrt[2])]^2 - PolyLog[2, (-1)^(1/4)/(1 + Sqrt[2])]
};
In[86]:= sum2 = FullSimplify[%]
2
Out[86]= (16 Catalan - 2 I (-3 + Sqrt[2]) Pi -
> 8 ArcCot[1 + Sqrt[2]] Log[2] + ArcCot[1 - Sqrt[2]] Log[256] +
> 16 ArcCot[1 + Sqrt[2]] Log[2 - Sqrt[2]] -
> 16 ArcCot[1 - Sqrt[2]] Log[2 + Sqrt[2]] +
> Pi (-2 EulerGamma - 2 I (-8 + Sqrt[2]) ArcCot[1 - Sqrt[2]] +
> 2 I Sqrt[2] ArcCot[1 + Sqrt[2]] + 4 ArcSinh[1] - 8 Log[2] +
> 5 Log[2 - Sqrt[2]] - Sqrt[2] Log[2 - Sqrt[2]] +
> 3 Log[2 + Sqrt[2]] + Sqrt[2] Log[2 + Sqrt[2]] - Log[99 + 70 Sqrt[2]]
1/4
> ) - 8 I Sqrt[2] PolyLog[2, -(-1) ] +
1/4
> 8 I Sqrt[2] PolyLog[2, (-1) ]) / 4
Finally, combining the values of sum1 and sum2, we get
In[87]:= FullSimplify[(EulerGamma*Pi)/8 + 1/4*Pi*Log[2] + (sum1 + sum2)/4]
2
Out[87]= (16 Catalan + 6 I Pi + 16 I Pi ArcCot[1 - Sqrt[2]] +
> 4 Pi ArcSinh[1] - 2 ArcCot[1 + Sqrt[2]] Log[16] +
> ArcCot[1 - Sqrt[2]] Log[256] + 5 Pi Log[2 - Sqrt[2]] +
> 16 ArcCot[1 + Sqrt[2]] Log[2 - Sqrt[2]] + 3 Pi Log[2 + Sqrt[2]] -
> 16 ArcCot[1 - Sqrt[2]] Log[2 + Sqrt[2]] - Pi Log[1584 + 1120 Sqrt[2]])\
> / 16
Then, performing another chain of simplification rules, we obtain the desirable result:
In[88]:= %/.ArcCot[1 - Sqrt[2]]->-ArcCot[1 + Sqrt[2]]-Pi/4;
In[89]:= Collect[%,ArcCot[1 + Sqrt[2]],FullSimplify]
Log[16] Log[256]
Out[89]= ArcCot[1 + Sqrt[2]] (-I Pi - ------- - -------- + Log[2 - Sqrt[2]] +
8 16
> Log[2 + Sqrt[2]]) + (64 Catalan +
> Pi (8 I Pi + 16 ArcSinh[1] - Log[256] + 20 Log[2 - Sqrt[2]] +
> 28 Log[2 + Sqrt[2]] - 4 Log[1584 + 1120 Sqrt[2]])) / 64
In[90]:= %//.r1_. Log[w_] + r2_. Log[e_] :> Log[w^r1 e^r2//Expand]
Out[90]= -I Pi ArcCot[1 + Sqrt[2]] +
> (64 Catalan + Pi (8 I Pi + 16 ArcSinh[1] +
37814272 26738688 Sqrt[2]
> Log[---------------------- + ----------------------])) / 64
4 4
(1584 + 1120 Sqrt[2]) (1584 + 1120 Sqrt[2])
In[91]:= TrigToExp[%]/.Log[w_] :> Log[w//FullSimplify]
-I 2
Out[91]= -- Pi + (64 Catalan +
8
> Pi (8 I Pi + Log[665857 - 470832 Sqrt[2]] + 16 Log[1 + Sqrt[2]])) / 64
In[92]:= %//.r1_. Log[w_] + r2_. Log[e_] :> Log[w^r1 e^r2//Expand]
2
-I 2 64 Catalan + 8 I Pi
Out[92]= -- Pi + --------------------
8 64
In[93]:= Expand[%]
Out[93]= Catalan
In[94]:=
-1/4*Sum[1/4096^k (1/(1 + 8*k)^2 + 1/2 1/(2 + 8*k)^2 +
1/8 1/(3 + 8*k)^2 - 1/64 1/(5 + 8*k)^2 -
1/128 1/(6 + 8*k)^2 - 1/512 1/(7 + 8*k)^2), {k, 0, Infinity}] +
3/2*Sum[1/16^k (1/(1 + 8*k)^2 - 1/(2 + 8*k)^2 +
1/2 1/(3 + 8*k)^2 - 1/4 1/(5 + 8*k)^2 +
1/4 1/(6 + 8*k)^2 - 1/8 1/(7 + 8*k)^2), {k, 0, Infinity}]//Expand
1 1 1 1
-LerchPhi[----, 2, -] LerchPhi[----, 2, -]
4096 8 4096 4
Out[95]= --------------------- - -------------------- -
256 512
1 3 1 5 1 3
LerchPhi[----, 2, -] LerchPhi[----, 2, -] LerchPhi[----, 2, -]
4096 8 4096 8 4096 4
> -------------------- + -------------------- + -------------------- +
2048 16384 32768
1 7 1 1 1 1
LerchPhi[----, 2, -] 3 LerchPhi[--, 2, -] 3 LerchPhi[--, 2, -]
4096 8 16 8 16 4
> -------------------- + -------------------- - -------------------- +
131072 128 128
1 3 1 5 1 3
3 LerchPhi[--, 2, -] 3 LerchPhi[--, 2, -] 3 LerchPhi[--, 2, -]
16 8 16 8 16 4
> -------------------- - -------------------- + -------------------- -
256 512 512
1 7
3 LerchPhi[--, 2, -]
16 8
> --------------------
1024
Using the integral representation for the Lerch function:
and changing the variable of integration 
, we obtain
Evaluating the integral, we found that
In[96]:= Integrate[(2/(8 - 4*x + x^2) - 3/(2 + 2*x + x^2))*Log[x],{x,0,1}]
I 1 I 1 I
Out[96]= - (3 PolyLog[2, -(-) - -] - 3 PolyLog[2, -(-) + -] -
2 2 2 2 2
1 I 1 I
> PolyLog[2, - - -] + PolyLog[2, - + -])
4 4 4 4
From the Kummer equation
with x = -I, y = 1 - I and x = -I, y = 1 + I correspondently, we find
From the dublication formula
we find
Applying these formulas along with identities for 
and 
to Out[96], we obtain
In[97]:= FullSimplify[%//.{
PolyLog[2, 1/4 + I/4] -> Pi^2/12 + Log[1 - I]^2/2 - Log[2]^2/2 +
PolyLog[2, -1/2 + I/2] + PolyLog[2, -I/2] + PolyLog[2, 1/2 + I/2],
PolyLog[2, 1/4 - I/4] -> Pi^2/12 + Log[1 + I]^2/2 - Log[2]^2/2 +
PolyLog[2, -1/2 - I/2] + PolyLog[2, I/2] + PolyLog[2, 1/2 - I/2],
PolyLog[2, -1/2 + I/2]->PolyLog[2, -I/2]/2-PolyLog[2, 1/2 - I/2],
PolyLog[2, -1/2 - I/2]-> PolyLog[2, I/2]/2 - PolyLog[2, 1/2 + I/2],
PolyLog[2, 1/2 - I/2] -> -I*Catalan + Pi^2/48 - 1/2*Log[1/2 + I/2]^2,
PolyLog[2, 1/2 + I/2] -> I*Catalan + Pi^2/48 - 1/2*Log[1/2 - I/2]^2
}]
Out[97]= Catalan